// -------------------------------------------------------------------------
// @OneWire.ino
//
//   Aaron Ardiri
// -------------------------------------------------------------------------

#include <OneWire.h>

#define ONE_WIRE_PIN           3

#define ONE_WIRE_DS18B20       0x28
#define ONE_WIRE_DS18B20_DELAY 1000

OneWire  onewire(ONE_WIRE_PIN);

void setup(void)
{
  Serial.begin(9600);

  // wait for the serial monitor to come alive
  delay(500);

  // print a small banner for information purposes
  Serial.println("OneWire Sketch");
  Serial.println("--------------");
  Serial.println();
  Serial.println("author:  Aaron Ardiri");
  Serial.println("version: " __DATE__);
  Serial.println();
}

void loop(void)
{
  byte  i;
  byte  present = 0;
  byte  type_s;
  byte  data[12];
  byte  addr[8];
  float celsius, fahrenheit;

  // do we have no more addresses?
  if (!onewire.search(addr))
  {
    Serial.println("No more addresses.");
    Serial.println();
    onewire.reset_search();
    delay(250);
    return;
  }

  // display the ROM of the device
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    if (addr[i] < 16) Serial.print("0");
    Serial.print(addr[i], HEX);
  }

  // lets check that the CRC matches (possible garbage on line)
  if (OneWire::crc8(addr, 7) != addr[7])
  {
    Serial.println("CRC is not valid!");
    return;
  }
  Serial.println();    

  // the first ROM byte indicates which chip
  switch (addr[0]) 
  {
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    default:
      Serial.println("  Chip is not a  DS18B20 - ignoring.");
      return;
  } 

  // select the device and start the conversion with parasite power
  onewire.reset();
  onewire.select(addr);
  onewire.write(0x44, 1);
  
  // wait a short period of time for the conversion to be done
  delay(ONE_WIRE_DS18B20_DELAY);

  // read the scratch pad by powering up the line
  onewire.reset();
  onewire.select(addr);    
  onewire.write(0xBE);        

  // display the raw data
  Serial.print("  Data = ");
  for ( i = 0; i < 9; i++) 
  {
    data[i] = onewire.read();
    if (data[i] < 16) Serial.print("0");
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // convert the data to actual temperature
  int16_t raw = (data[1] << 8) | data[0];
  {
    byte cfg = (data[4] & 0x60);

    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7; // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;

  // display the resulting temperature recorded by the device
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}

// -------------------------------------------------------------------------